在Delphi2007中的字符串中插入表情符号

我正在努力完成标题所说的内容,在Delphi 2007中将表情符号插入到字符串中,就像下面的例子一样:

procedure TForm1.Button1Click(Sender: TObject);
var s : string;
begin
s := 'This is my original string (y)';
s := ansireplacestr(s,'(y)','');
showmessage(s);
end;

我甚至可以将表情符号粘贴到IDE的代码中,但在运行时showmessage结果如下:

这是我原来的字符串????

有没有办法在Delphi 2007中实现这个任务？由于几个原因我现在无法升级Delphi.

有人说我的问题在这个主题上得到了解决:

在Delphi版本中处理Unicode字符串<= 2007

但是这个主题只是说使用第三方组件,而没有确切知道如何去做.

编辑:建议后,我尝试使用函数pos,删除和插入以及宽带var:

function addEmoji(mystring : widestring) : widestring;
var r, aux : widestring;
p : integer;
begin
r := mystring;
while pos('(y)',r) > 0 do
  begin
    aux := r;
    p := pos('(y)',aux);
    Insert('',aux,p);
    delete(aux,pos('(y)',aux),3);
    r := aux;
  end;
result := r;
end;

但结果是'(y)'被'????'取代.

在Delphi 2007中,默认string类型是AnsiString.Emojis需要Unicode处理,因为它们使用的高Unicode代码点在大多数常用的Ansi编码中都不适合/存在.因此,您需要使用Unicode UTF编码(UTF-7,-8,-16或-32).

您可以使用AnsiStringUTF-7 ¹或UTF8String²表示UTF-8,或WideStringUTF-16或UCS4String³表示UTF-32.

¹:UTF-7是7位ASCII兼容编码.

²:UTF8String确实存在于Delphi 2007中(它是在Delphi 6中引入的),但它不是真正的 UTF-8字符串类型,它只是一个别名,AnsiString期望它始终包含UTF-8编码数据.您必须使用UTF8Encode()并UTF8Decode()确保通过UTF-16正确转换为其他编码. UTF8String在Delphi 2009之前没有成为真正的 UTF-8字符串类型(UTF8Encode()并且UTF8Decode()也被弃用).

³:UCS4String自Delphi 6以来也存在,但它根本不是真正的字符串类型(即使在现代的Delphi版本中).它只是一个别名array of UCS4Char.

RTL对UTF-7没有任何原生支持(但手动实现并不困难),并且对UTF-32的支持很少(仅为了促进UTF-16 <- > UTF-32之间的转换),所以你应该在你的代码中坚持使用UTF-8或UTF-16.

如果将UTF数据转换为Ansi,您将丢失表情符号数据,例如,如果您传递WideString给ShowMessage().您可以WideString改为传递给Win32 API MessageBoxW()函数,并且您不会有任何数据丢失,但是根据对话框使用的字体,表情符号可能会或可能不会正确显示(但它不会显示为??,至少) .

但是,Delphi 2007中的原生RTL根本不支持您尝试的内容,至少不支持UTF-16.你必须找到一个第三方的WideString基于功能,或者只使用RTL的编写自己的Pos(),Delete()和Insert()内在的功能,这是重载WideString数据,例如:

function WideReplaceStr(const S, FromText, ToText: WideString): WideString;
var
  I: Integer;
begin
  Result := S;
  repeat
    I := Pos(FromText, Result);
    if I = 0 then Break;
    Delete(Result, I, Length(FromText));
    Insert(ToText, Result, I);
  until False;
end;

var
  s : WideString;
begin
  s := 'This is my original string (y)';
  s := WideReplaceStr(s, '(y)', '');
  MessageBoxW(0, PWideChar(s), '', MB_OK);
end; 

但是,使用UTF-8,您可以使用本机RTL完成相同的操作,但您仍然无法使用ShowMessage()(嗯,您可以,但它不会正确显示非ASCII字符):

var
  s : UTF8String;
begin
  s := UTF8Encode('This is my original string (y)');
  s := AnsiReplaceStr(s, '(y)', UTF8Encode(''));
  MessageBoxW(0, PWideChar(UTF8Decode(s)), '', MB_OK);
end;

无论哪种方式,请确保您的代码编辑器设置为.pas以UTF-8 保存文件,否则您不能使用文字'',您将不得不使用更像这样的东西:

var
  Emoji: WideString;

SetLength(Emoji, 2);
Emoji[1] := WideChar($D83D);
Emoji[2] := WideChar($DC4D);

然后你可以这样做:

var s: WideString;
...
s := WideReplaceStr(s, '(y)', Emoji);

要么:

var s: UTF8String;
...
s := AnsiReplaceStr(s, '(y)', UTF8Encode(Emoji));