VB如何跳出选择文件对话框？

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long



Private Sub Form_Load()



        On Error GoTo ms:

        With Me.CommonDialog1

            .Filter = "所有文件|*.*"

            .ShowOpen

        End With

        

        Dim strFileName  As String

        strFileName = Me.CommonDialog1.filename

        If Len(strFileName) > 0 And Dir(strFileName) <> "" Then

            ShellExecute Me.hWnd, "Open", strFileName, vbNullString, vbNullString, 1

        End If

          

ms:

      

End Sub

dim fn as string

fn=xlApp.openfilename

'========================打开/保存对话框 API 函数及结构===================

Private Type tagOPENFILENAME

   lStructSize As Long        '结构大小

   hwndOwner As Long          '

   hInstance As Long          '

   strFilter As String        '过滤器字符串

   strCustomFilter As String '选中的过滤器（过滤器索引所指的过滤器）字符串

   nMaxCustFilter As Long     '过滤器最大长度

   nFilterIndex As Long       '选中的过滤器索引，意义与 CommonDialog 控件相同

   strFile As String          '选中的全路径文件名

   nMaxFile As Long           '装载全路径文件名的字符串长度

   strFileTitle As String     '去掉了路径的文件名

   nMaxFileTitle As Long      '装载去掉了路径的文件名字符串长度

   strInitialDir As String    '去掉了文件名的路径（没有最后的反斜杠）

   strTitle As String         '对话框标题，意义与 CommonDialog 控件相同

   flags As Long              '标志，意义与 CommonDialog 控件相同

   nFileOffset As Integer     '路径长度（包括最后的反斜杠）

   nFileExtension As Integer '全路径文件名长度（不计算前面 3 个表示盘符的字符，如 D:\）

   strDefExt As String        '默认提取

   lCustData As Long          '

   lpfnHook As Long           '勾子函数地址

   lpTemplateName As String   '

End Type



Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (ofn As tagOPENFILENAME) As Boolean

Private Declare Function GetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameA" (ofn As tagOPENFILENAME) As Boolean





'返回选择的文件名。输入参数：

'1.对话框类型（0＝保存，1＝打开）；2.对话框标题；3.过滤器字符串

'4.过滤器索引；5.标志；6.路径；7.文件名

Public Function CmdDlg(Optional ByVal DlgType As Boolean = True, _

   Optional ByVal DialogTitle As String, Optional ByVal Filter As String, _

   Optional FilterIndex As Long = 1, Optional flags As Long, _

   Optional ByVal InitialDir As String, Optional ByVal FileName As String, Optional ByRef hWnd As Long = 0) As String

  

On Error GoTo CmdDlg_Error

Dim ofn As tagOPENFILENAME

Dim fResult As Boolean

If InitialDir = "" Then InitialDir = CurDir

If Len(Filter) > 0 Then Filter = Replace(Filter, "|", vbNullChar) 'Filter以Chr(0)为分隔符



With ofn

   .lStructSize = Len(ofn)

   .hwndOwner = hWnd                                   '0为屏幕句柄

   .strFilter = Filter

   .nFilterIndex = FilterIndex

   .strFile = Left(FileName & String$(255, 0), 255)   '用空字符补足全路径文件名255字节

   .nMaxFile = 255                                    '全路径文件名长度

   .strFileTitle = String$(255, 0)                    '用空字符填充(去掉路径的)文件名

   .nMaxFileTitle = 255                               '(去掉路径的)文件名长度

   .strTitle = DialogTitle                            '对话框标题

   .flags = flags

   .strDefExt = ""

   .strInitialDir = InitialDir

   .hInstance = 0

   .strCustomFilter = String(255, 0)                  '用空字符填充选中的过滤器

   .nMaxCustFilter = 255                              '选中的过滤器长度

   .lpfnHook = 0

End With

If DlgType Then fResult = GetOpenFileName(ofn) Else fResult = GetSaveFileName(ofn)

If fResult Then

   CmdDlg = Left(ofn.strFile, InStr(ofn.strFile, vbNullChar) - 1)

   'FilterIndex = ofn.nFilterIndex                    '返回选中的过滤器索引

Else

   CmdDlg = vbNullChar

End If

CmdDlg_Error:

End Function

With CreateObject("MSComDlg.CommonDialog")

 .showopen

 If .FileName <> "" Then

  '在此加上选中文件的处理操作

 End If

End With

Application.GetOpenFilename